From e2006ae6b407bf55925312e05f96d790d4c22cba Mon Sep 17 00:00:00 2001
From: Josh Triplett <josh@joshtriplett.org>
Date: Thu, 6 Aug 2009 07:57:01 -0700
Subject: [PATCH] --- yaml --- r: 158451 b: refs/heads/master c:
 6591b493871cf9b17de2ba272edb8ab529a8058b h: refs/heads/master i:   158449:
 815afcfb83c8a078fc76031be9e50f45c95601b3   158447:
 b7959c43f7a3e27dc973d4a350ed2727a4f0b152 v: v3

---
 [refs]                                        |  2 +-
 .../trace/function-graph-fold.vim             | 42 +++++++++++++++++++
 2 files changed, 43 insertions(+), 1 deletion(-)
 create mode 100644 trunk/Documentation/trace/function-graph-fold.vim

diff --git a/[refs] b/[refs]
index bfe3635744ec..fa8b3a63fb80 100644
--- a/[refs]
+++ b/[refs]
@@ -1,2 +1,2 @@
 ---
-refs/heads/master: f0693c8bd5c50380b299e19d19e7640024640b42
+refs/heads/master: 6591b493871cf9b17de2ba272edb8ab529a8058b
diff --git a/trunk/Documentation/trace/function-graph-fold.vim b/trunk/Documentation/trace/function-graph-fold.vim
new file mode 100644
index 000000000000..0544b504c8b0
--- /dev/null
+++ b/trunk/Documentation/trace/function-graph-fold.vim
@@ -0,0 +1,42 @@
+" Enable folding for ftrace function_graph traces.
+"
+" To use, :source this file while viewing a function_graph trace, or use vim's
+" -S option to load from the command-line together with a trace.  You can then
+" use the usual vim fold commands, such as "za", to open and close nested
+" functions.  While closed, a fold will show the total time taken for a call,
+" as would normally appear on the line with the closing brace.  Folded
+" functions will not include finish_task_switch(), so folding should remain
+" relatively sane even through a context switch.
+"
+" Note that this will almost certainly only work well with a
+" single-CPU trace (e.g. trace-cmd report --cpu 1).
+
+function! FunctionGraphFoldExpr(lnum)
+  let line = getline(a:lnum)
+  if line[-1:] == '{'
+    if line =~ 'finish_task_switch() {$'
+      return '>1'
+    endif
+    return 'a1'
+  elseif line[-1:] == '}'
+    return 's1'
+  else
+    return '='
+  endif
+endfunction
+
+function! FunctionGraphFoldText()
+  let s = split(getline(v:foldstart), '|', 1)
+  if getline(v:foldend+1) =~ 'finish_task_switch() {$'
+    let s[2] = ' task switch  '
+  else
+    let e = split(getline(v:foldend), '|', 1)
+    let s[2] = e[2]
+  endif
+  return join(s, '|')
+endfunction
+
+setlocal foldexpr=FunctionGraphFoldExpr(v:lnum)
+setlocal foldtext=FunctionGraphFoldText()
+setlocal foldcolumn=12
+setlocal foldmethod=expr