Permalink
Cannot retrieve contributors at this time
Name already in use
A tag already exists with the provided branch name. Many Git commands accept both tag and branch names, so creating this branch may cause unexpected behavior. Are you sure you want to create this branch?
glibc/scripts/gen-posix-conf-vars.awk
Go to fileThis commit does not belong to any branch on this repository, and may belong to a fork outside of the repository.
89 lines (77 sloc)
2.27 KB
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
# Generate posix-conf-vars-def.h with definitions for CONF_DEF{CONF} for each | |
# configuration variable that getconf or sysconf may use. Currently it is | |
# equipped only to generate such macros for specification macros and for | |
# SYSCONF macros in the _POSIX namespace. | |
BEGIN { | |
prefix = "" | |
} | |
$1 ~ /^#/ || $0 ~ /^\s*$/ { | |
next | |
} | |
# Begin a new prefix. | |
$NF == "{" { | |
type = $1 | |
prefix = $2 | |
if (NF == 4) | |
sc_prefix = $3 | |
else | |
sc_prefix = "_SC" | |
next | |
} | |
$1 == "}" { | |
prefix = "" | |
type = "" | |
sc_prefix = "" | |
next | |
} | |
{ | |
if (prefix == "" && type == "" && sc_prefix == "") { | |
printf ("Syntax error at %s:%d\n", FILENAME, FNR) > "/dev/stderr" | |
exit 1 | |
} | |
# The prefix and variable names are indices and the value indicates what type | |
# of variable it is. The possible options are: | |
# CONFSTR: A configuration string | |
# SYSCONF: A numeric value | |
# SPEC: A specification | |
sc_prefixes[prefix][$1] = sc_prefix | |
conf[prefix][$1] = type | |
} | |
END { | |
print "/* AUTOGENERATED by gen-posix-conf-vars.awk. DO NOT EDIT. */\n" | |
# Generate macros that specify if a sysconf macro is defined and/or set. | |
for (p in conf) { | |
for (c in conf[p]) { | |
printf "#ifndef _%s_%s\n", p, c | |
printf "# define CONF_DEF_%s_%s CONF_DEF_UNDEFINED\n", p, c | |
# CONFSTR have string values and they are not set or unset. | |
if (conf[p][c] != "CONFSTR") { | |
printf "#else\n" | |
printf "# if _%s_%s > 0\n", p, c | |
printf "# define CONF_DEF_%s_%s CONF_DEF_DEFINED_SET\n", p, c | |
printf "# else\n" | |
printf "# define CONF_DEF_%s_%s CONF_DEF_DEFINED_UNSET\n", p, c | |
printf "# endif\n" | |
} | |
printf "#endif\n\n" | |
# Build a name -> sysconf number associative array to print a C array at | |
# the end. | |
if (conf[p][c] == "SPEC") { | |
name = sprintf ("%s_%s", p, c) | |
num = sprintf ("%s_%s", sc_prefixes[p][c], c) | |
spec[name] = num | |
} | |
} | |
} | |
# Print the specification array. Define the macro NEED_SPEC_ARRAY before | |
# including posix-conf-vars.h to make it available in the compilation unit. | |
print "#if NEED_SPEC_ARRAY" | |
print "static const struct { const char *name; int num; } specs[] =" | |
print " {" | |
for (s in spec) { | |
printf " { \"%s\", %s },\n", s, spec[s] | |
} | |
print " };" | |
print "static const int nspecs = sizeof (specs) / sizeof (specs[0]);" | |
print "#endif" | |
} |